Turbo51学习笔记（8） 51单片机端的串行通信代码

逍遥派掌门人 · 发表于 2015-1-16 23:49:53

本帖最后由逍遥派掌门人于 2015-1-16 23:58 编辑

在不同设备上进行数据交换，最价廉物美的莫过于串行通信（RS232）了，有关串行通信的点滴可自行去百度搜索。

在以下的篇幅里，展示51单片机如何与计算机进行通信，本节解析51单片机的Turbo51代码，下一节解析计算机端的Lazarus代码。

先上51单片机的硬件电路图，

图里有1个绿色的LED和1个蓝色的LED，计算机通过RS232控制这两个LED的亮灭。

逍遥派掌门人 · 发表于 2015-1-17 00:05:01

在通信之前，必须约定一个握手的协议，以保证通信的正确无误。此工作非常重要。
通信协议可采用各种流行的协议，也可以自行约定。为了简化代码，自设定如下的通信协议：

1、  上位机 ==> 单片机
   格式：  起始字  + 单片机地址  +  命令  +  校验
            1byte    1byte       1byte 1byte    =  4 byte

   其中：
         起始字，固定为：    $7E
         单片机地址，固定为： $01
         命令，控制单片机的动作：
               = $00    同时灭两个LED
               = $01    亮绿色LED，灭蓝色LED
               = $02    灭绿色LED，亮蓝色LED
               = $03    同时亮两个LED
         校验，为前面3个字节的累加和

2、  单片机 ==> 上位机
   格式：  起始字  + 单片机地址  +  命令  +  参数  +  校验
            1byte    1byte       1byte 1byte 1byte =  5 byte

   其中：
         起始字，固定为：    $7E
         单片机地址，固定为： $01
         命令，来自计算机端：
               = $00    同时灭两个LED
               = $01    亮绿色LED，灭蓝色LED
               = $02    灭绿色LED，亮蓝色LED
               = $03    同时亮两个LED
         参数，将当前单片机的控制状态反馈给计算机
               = $00    两个LED都灭
               = $01    绿色LED亮，蓝色LED灭
               = $02    绿色LED灭，蓝色LED亮
               = $03    两个LED都亮
         校验，为前面4个字节的累加和

逍遥派掌门人 · 发表于 2015-1-17 00:21:46

//定义用到的常量

Const
BaudRate = 9600; {通信用的波特率}
Header = $7E; {起始字}
Address = $01; {单片机地址}
TX_Length = 5 ; {按照协议，发送的字节数}
RX_Length = 4 ; {按照协议，接收的字节数}
Port_Mask = $03; {这里与LED有关}

复制代码

//定义用到的变量

var
Port_Get : byte absolute P1;
LED_green: Boolean absolute P1.0;
LED_blue : Boolean absolute P1.1;
RX_Buffer: Array [1..RX_Length] of Byte; {接收缓冲区}
RX_Count : Byte;
TX_Buffer: Array [1..TX_Length] of Byte; {发送缓冲区}
TX_Count : Byte;
RX_right : Boolean;
TX_right : Boolean;
TX_Need : Boolean;

复制代码

逍遥派掌门人 · 发表于 2015-1-17 00:28:21

本帖最后由逍遥派掌门人于 2015-1-17 00:38 编辑

51单片机的接收和发送都进入同一个串行中断，而且是接收或发送一个字节就产生一个中断，故此，关键的串行中断代码如下：

Procedure RS232; Interrupt Serial;
begin
If (RI = True) then {接收中断}
begin
RI := False;
if (RX_right = False) then
begin
RX_Buffer[RX_Count] := SBUF; {接收字节}
inc(RX_Count);
if (RX_Count > RX_Length) then RX_right := True; {判断是否接收完毕}
end;
end;
If (TI =True) then {发送中断}
begin
TI := False;
if (TX_right = False) then
begin
if TX_Count < (TX_Length + 1) then {判断是否已经发送完毕}
begin
SBUF := TX_Buffer [TX_Count]; {发送字节}
Inc (TX_Count);
end
else TX_right := True;
end;
end;
end;

复制代码

逍遥派掌门人 · 发表于 2015-1-17 00:44:30

本帖最后由逍遥派掌门人于 2015-1-17 00:46 编辑

//处理接收到的数据

Procedure Do_receive;
var
number : byte;
checksum : byte;
begin
if (RX_right = True) then
begin
if ((RX_Buffer[1] = Header) and (RX_Buffer[2] = Address)) then {判断是否合法}
begin
checksum := 0;
for number := 1 to (RX_Length-1) do checksum:= checksum + RX_buffer[number]; {计算校验和}
if (checksum = RX_buffer[RX_Length]) then {校验通过}
begin
case RX_buffer[3] of {判断命令}
$01:
begin
LED_green := False; {亮绿色LED}
LED_blue := True; {灭蓝色LED}
end;
$02:
begin
LED_green := True; {灭绿色LED}
LED_blue := False; {亮蓝色LED}
end;
$03:
begin
LED_green := False; {亮绿色LED}
LED_blue := False; {亮蓝色LED}
end;
$00:
begin
LED_green := True; {灭绿色LED}
LED_blue := True; {灭蓝色LED}
end;
end;
TX_Buffer[3] := RX_buffer[3];
TX_Need := True; {发送应答}
TX_Buffer[4] := (not Port_Get) and Port_Mask; { 获取LED控制脚的状态}
end;
end;
RX_Count := 1;
RX_right := False;
end;
end;

复制代码

逍遥派掌门人 · 发表于 2015-1-17 00:49:42

//待发送数据的预处理

Procedure Do_send;
var
number : byte;
checksum: byte;
begin
if (TX_Need = True) then
begin
checksum := 0;
for number := 1 to (TX_Length -1) do checksum := checksum + TX_Buffer[number]; {计算校验和}
TX_Buffer[TX_Length] := checksum;
TX_Count := 1;
TX_right := False;
TX_Need := False ;
TI := True; {开启发送}
end;
end;

复制代码

逍遥派掌门人 · 发表于 2015-1-17 00:52:36

本帖最后由逍遥派掌门人于 2015-1-17 00:54 编辑

//主循环

begin
Init; {初始化单片机，此处略}
Repeat
Do_receive;
Do_send;
until False;
end.

复制代码

单片机部分就此完成。

		自动登录	找回密码
密码			立即注册（注册审核可向QQ群索取）

[Lazarus实战宝典] Turbo51学习笔记（8） 51单片机端的串行通信代码

本帖子中包含更多资源

浏览过的版块